//**************
//header
//language files

if ([$MessageLanguage] == [español])

   @ $LXMsg_Kick_NoOp = *** No eres un OP en \b$channel\b.

else

   @ $LXMsg_Kick_NoOp = *** Not an OP in \b$channel\b.
   @ $LXMsg_Kick_Kickd = *** Uso de Kick Domain: /KickD [#channel] nick/mascara [mensaje]
   @ $LXMsg_Kick_Kickm = *** Uso de Kick Mask: /KickM [#channel] mascara [mensaje]

endif

//**************


//used alias

Alias kickfix
     if (([$lower($1)]==[$lower($2)]) || ([$1]==[$$C]))
        @ $fresult = $2-
     else
        @ $fresult = $1 $2-
     endif
EndAlias

Alias NickToMask
  @l $r = $GetAddress($1)
  if ([$r] == [unknown@unknown])
     @ $fresult = $1!*@*
  else
     @ $fresult = *!*@$strtokr(@ $r)
  endif
EndAlias

Alias NickToIgnoreMask
  @l $r = $GetAddress($1)
  if ([$r] == [unknown@unknown])
     @ $fresult = $1!*@*
  else
     @ $fresult = $1!*@$domainmask($strtokr(@ $r))
  endif
EndAlias

Alias DomainMask
  if ($isnumeric($strtokl(. $1)))
     @ $fresult = $rstrtokl(. $1).*
  else
     @ $fresult = *.$strtokr(. $1)
  endif
EndAlias


//the kicks

Alias k
  kick $kickfix($C $1-)
EndAlias

Alias kick
   if ([$1] == [])
    TextOut > $activewindow() ecERROR Uso de Kick: /Kick nick [mensaje]
    Halt
   Endif

   parse $kickfix($C $1-)
    @l $channel = $0
    @l $nicks = $1
    @l $message = $2-
   endparse

  //textout > . clRed $channel $nicks $message

   if (!$isop($N $channel))
    TextOut ecERROR $eval($LXMsg_Kick_NoOp)
    Halt
   Endif


   if ( [$message] == [])
     @l $message = $eval($GetSetting(KickMessage))
   endif

   @l $kicklist = $listsplit(, $nicks)
   ForEach ($kickee;$kicklist)
    *kick $channel $kickee $message ( # $LX.NoKick )
    @s $LX.NoKick = $($LX.NoKick + 1)
   EndForEach
EndAlias

Alias ban
  if ([$1] == [])
   TextOut > $activewindow() ecERROR Uso de Ban: /Ban [canal] <Nick/Máscara>
   Halt
  Endif

  parse $kickfix($C $1-)
   @l $channel = $0
   @l $nicks = $1
  endparse

  if (!$isop($N $channel))
   TextOut ecERROR $eval($LXMsg_Kick_NoOp)
   Halt
  Endif

  @l $banlist = $listsplit(, $nicks)
  ForEach ($banned;$banlist)
     if ($maskmatch($banned *!*@*))
        @l $banmask = $banned
     else
        @l $banmask = $NickToMask($banned)
     endif
     mode $channel -o+b $banned $banmask
  EndForEach
EndAlias

Alias bk

  if ([$1] == [])
   TextOut ecERROR Uso de BanKick: /BK [canal] <Nick> [Razon]
   Halt
  Endif

  parse $kickfix($C $1-)
   @l $channel = $0
   @l $nicks = $1
   @l $message = $2-
  endparse

  if (!$isop($N $channel))
   TextOut ecERROR $eval($LXMsg_Kick_NoOp)
   Halt
  Endif

  if ( [$message] == [])
    @l $message = $eval($GetSetting(KBMessage))
  endif

  @l $kicklist = $listsplit(, $nicks)
  ForEach ($kickee;$kicklist)
   if ($ison($kickee $channel))
     @l $banmask = $NickToMask($kickee)
     mode $channel -o+b $kickee $banmask
     kick $channel $kickee $message
    Else
     TextOut > $activewindow() ecERROR $kickee no esta presente en $channel.
     Continue
    Endif
  EndForEach
EndAlias

Alias tbk

   parse $kickfix($C $1-)
    @l $channel = $0
    @l $time = $1
    @l $nicks = $2
    @l $message = $3-
   endparse

  if (([$nicks] == []) || (!$isnumeric($time)))
     TextOut ecERROR Uso de TempBanKick: /TBK [canal] <Segundos de Ban> <Nick> [Razon]
     Halt
  Endif


  if (!$isop($N $channel))
     TextOut ecERROR $eval($LXMsg_Kick_NoOp)
     Halt
  Endif

  foreach ($x;$listsplit(, $nicks))

    if ($ison($x $channel))

      @l $temp = $NickToMask($x)
      mode $channel -o+b $x $temp
      kick $channel $x $message [Baneado por $decodeinterval($time)]
      ^timer $time 1 mode $channel -b $temp
    else
      TextOut > $channel ecERROR *** \b$2\b no esta presente en \b$channel\b.
  Endif

  endforeach
EndAlias


//undocumented mass kicks
//use at own risk

Alias kickip
  if ([$1] == [])
    TextOut > $C ecERROR $LXMsg_Kick_Kickip
    Halt
  Endif

   parse $kickfix($C $1-)
    @l $chan = $0
    @l $nck = $1
    @l $msg = $2-
   endparse

   if ($ison($nck $chan))
    @l $msk = $strtokr(@ $getaddress($nck))
   else
    @l $msk = $nck
   endif

   mode $chan +b *!*@$msk

   foreach ($n;$nicklist($chan))
     if ($maskmatch(*!*@$strtokr(@ $getaddress($n)) *!*@$msk))
        kick $chan $n $msg
     endif
   endforeach

EndAlias


Alias kickd
  if ([$1] == [])
    TextOut > $C ecERROR $LXMsg_Kick_Kickd
    Halt
  Endif

   parse $kickfix($C $1-)
    @l $chan = $0
    @l $nck = $1
    @l $msg = $2-
   endparse

   if ($ison($nck $chan))
    @l $msk = $domainmask($strtokr(@ $getaddress($nck)))
   else
    @l $msk = $nck
   endif

   mode $chan +b *!*@$msk

   foreach ($n;$nicklist($chan))
     if ($maskmatch(*!*@$strtokr(@ $getaddress($n)) *!*@$msk))
        kick $chan $n $msg
     endif
   endforeach

EndAlias


Alias kickm

  if ([$1] == [])
   TextOut > $C ecERROR $LXMsg_Kick_Kickm
   Halt
  Endif

  parse $kickfix($C $1-)
   @l $chan = $0
   @l $msk = $1
   @l $msg = $2-
  endparse

  mode $chan +b $msk

  foreach ($n;$nicklist($chan))
    if ($maskmatch($n!$getaddress($n) $msk))
       bk $chan $n $msg
    endif
  endforeach

EndAlias